Next: , Previous: Voices Chords and Polyphony (SAL), Up: SAL Examples

8.4 Articulation Markings

8.4.1 Single Note Marks

Marks are entered as strings. They are attached to a note event via the marks parameter. 

process myproc ()
  with marks = {{} {"."} {">"} {"^"} {"!"} {"/."}}
  repeat 21
  fms:note(dur: #?(elapsed() < 10, 1/2, 1),
           pitch: between(48, 73),
           marks: marks[random(length(marks))])
  wait 1/2
end

begin
  with parts = {{:id "apart" :inst "piano"}}
  sprout(myproc(), *filename*, parts: parts)
end

sal002.png

Figure 8.19: Articulation

Custom text marks are entered by enclosing an x, x^, x_ or x! mark in a list with the text to appear in the score. x places the text at the notehead, x^ and x_ force the text to appear above or below the note in italics, and x! places the text in bold face above the staff. 

process myproc ()
  with marks = {{}
                {{"x" "text"}} {} {} {}
                {{"x^" "text above"}} {} {} {}
                {{"x_" "text below"}} {} {} {}
                {{"x!" "text text"}} {} {} {}
                {} {} {} {}}
  repeat 21
  for m in marks
  fms:note(dur: #?(elapsed() < 10, 1/2, 1),
           pitch: between(48, 51),
           marks: m)
  wait 1/2
end

begin
  with parts = {{:id "ce" :inst "cello"}}
  sprout(myproc(), *filename*, parts: parts)
end

sal038.png

Figure 8.20: Text Marks

FOMUS has many built in text marks that can be customized using the default-mark-texts and mark-texts settings. The following example uses mark-texts to change the appearance of the vib and moltovib text marks (by default, FOMUS uses the texts “vib.” and “molto vib.”). 

process myproc ()
  with marks = {"vib" "moltovib" {} {}}
  repeat 21
  fms:note(dur: #?(elapsed() < 10, 1/2, 1),
           pitch: between(48, 50),
           marks: nth(marks, floor(elapsed() / 3)))
  wait 1/2
end

begin
  with sets = {:mark-texts {"vib" "vibrato" "moltovib" "molto vibrato"}},
       parts = {{:id "ce" :inst "cello"}}
  sprout(myproc(), *filename*, sets: sets, parts: parts)
end

sal039.png

Figure 8.21: More Text Marks

If you wanted to make this the default appearance for these two marks, you could insert the following line in your .fomus file located in your home directory (make sure you use ‘+=’ instead of ‘=’ to append the values to FOMUS's default list): 

     default-mark-texts += (vib "vibrato", moltovib "molto vibrato")